8. Werken met objecten

8.1 Objectvariabelen

Microsoft Access kent objecten als tabellen, query's, formulieren en rapporten waarmee taken voor gegevensbeheer worden uitgevoerd. 

Er zijn verschillende soorten objecten

• Microsoft Access-objecten: enkel te gebruiken in access bijvoorbeeld form, report, control
• Data Access (DAO)-objecten: ook te gebruiken in andere programmeeromgevingen als visual basic bijvoorbeeld recordset, tabledef, querydef.

De verschillende objecten worden verzameld in collecties en worden bewaard volgens een hiërarchisch objectenmodel.

Elk object kent eigenschappen en wordt bestuurd met methodes

De volgende tabel toont de hiërarchische structuur van de objecten:

Het Application-object bevat alle Microsoft Access-objecten en -collecties
Forms is de collectie van alle geopende formulieren, terwijl Reports de collectie is van alle geopende rapporten. De elementen van een form worden bewaard in de controls-collectie.

Een object uit een collectie kan op drie manieren aangesproken worden

1. naam van de collectie ! [naam van het object]
   voorbeeld : forms![form1]
2. naam van de collectie ("naam van het object")
   voorbeeld : forms("form1")
   voordeel : hetgeen tussen de haakjes staat kan eventueel een variabele zijn : naam = "form1"
   de aanspreekvorm wordt dan : forms(naam)
3. naam van de collectie (indexnummer)
   Bij het openen van bijvoorbeeld een form krijgt die een nummer (indexnummer). Is bijvoorbeeld form1 als eerste geopend dan krijgt die de index 0. De aanspreekvorm is dan : form(0).
   

In de programmacode kan men deze objecten toekennen aan een variabele. Na het declareren kan men een waarde toekennen, net zoals men een getal of een string toekent aan een variabele.
Een objectvariabele moet net als een gewone variabele gedeclareerd worden :

Hierbij zijn f en c de variabelen. In de naam van de variabelen zijn alle tekens toegelaten behalve leestekens. Underscore is ook toegelaten.

Om een waarde te stockeren in een objectvariabele gaat men als volgt te werk :

Set f = forms![naam van een geopend formulier]  of
Set f = forms!("naam van een geopend formulier") of
Set f = forms(0) indien het formulier het eerst geopend werd

Een voorbeeld maakt dit duidelijk :

• We maken een formulier gebaseerd  op tblLeerlingen en plaatsen   de velden naam en klascode. Het formulier bewaren we met naam frmLeerlingen_o. Het formulier wordt geopend in formulierweergave en geminimaliseerd
• In het modulevenster creëren we volgende functieprocedure

  function Leerlingen_o()
  Dim f as form 'declareren van de objectvariabele f
  Set f = forms![frmLeerlingen_o] 'het geopend formulier in de variabele stockeren
  end function

• Elk object heeft een aantal eigenschappen, die we als volgt kunnen aanspreken.

  forms![naam van een geopend formulier].eigenschap of
  f.eigenschap (indien het object in de variabele f bewaard werd)

  De eigenschappen worden in het Engels aangeduid, dus niet standaardweergave maar defaultview
  Op te weten op welke tabel het huidig geopend formulier gebaseerd is, kan men volgende regel aan de functie toevoegen:

  Msgbox f.recordsource

  Activeert men vanuit het foutopsporingsvenster de functie met ? Leerlingen_o() dan krijgt men het volgend resultaat.

  

• We kunnen niet alleen de waarde van de recordsource oproepen maar ook veranderen.
  Maak een kopie van de structuur van de tabel tblLeerlingen naar tblOudleerlingen. Voer enkele records toe in de nieuwe tabel.
  
  In de tabel tblLeerlingen en tblOudleerlingen komen de velden naam en klascode voor. We kunnen hetzelfde formulier frmLeerlingen_o gebruiken voor beide tabellen.
  Eerst zorgt een macroactie dat het formulier zeker geopend werd.
  Na de tabelkeuze wordt naast de recordsource ook de caption-eigenschap aangepast.
  

  Function Leerlingen_o()
  Dim f As Form 'declareren van de objectvariabele f
  Dim keuze As Integer 'declareren van de variabele voor het bewaren van een getal
  DoCmd.OpenForm "frmLeerlingen_o" 'openen van het formulier met een macroactie
  Set f = Forms![frmLeerlingen_o] 'het geopend formulier in de variabele stockeren
  keuze = InputBox("1=leerlingen, 2=oudleerlingen") 'invoer van de keuze
  If keuze = 1 Then
  f.RecordSource = "tblLeerlingen"
  f.Caption = "tabel van de leerlingen"
  Else
  f.RecordSource = "tblOudleerlingen"
  f.Caption = "tabel van de oudleerlingen"
  End If
  End Function

• De verschillende objecten als knoppen, velden,... die op een formulier voorkomen noemt men controls.
  Het volgende voorbeeld zorgt dat de naam van de huidige actieve record van de tabel tblLeerlingen in een venster afgedrukt wordt  en de klascode onzichtbaar gemaakt wordt.
  
  Function Leerlingen_o()
  Dim f As Form, c1 As Control, c2 As Control 'declareren van de objectvariabelen
  DoCmd.OpenForm "frmLeerlingen_o" 'openen van het formulier met een macroactie
  Set f = Forms![frmLeerlingen_o] 'het geopend formulier in de variabele stockeren
  Set c1 = f![naam] 'het veld naam wordt in de variabele c1 gestockeerd
  Set c2 = f![klascode] 'het veld klascode wordt in de variabele c2 gestockeerd
  MsgBox c1 'de naam in een venster
  c2.Visible = 0 'de klascode onzichtbaar
  End Function

Bijzondere eigenschappen bij objecten en collecties zijn count en name. Bovendien is properties de collectie van alle property's of eigenschappen. Een voorbeeld

• Zorg dat het formulier frmLeerlingen_o geopend en geminimaliseerd werd.
• Ga naar het foutopsporingsvenster en voer volgende opdrachten in:
  • ? forms.count wat resulteert in het aantal momenteel geopende formulieren
  • ? forms(0).name geeft de naam van het eerste geopend formulier
  • ? forms(0).properties.count toont het aantal eigenschappen van het eerste geopend formulier
  • ? forms(0).properties(0).name toont de eerste eigenschap van het eerste geopend formulier
  • ? forms(0).controls.count toont het aantal besturingselementen op het formulier
  • ? forms(0).controls(0).name toont de naam van het eerste besturingselement
  • ? forms(0).controls(0).properties(0).name toont de naam van de eerste eigenschap van het eerste besturingselement van het eerste geopend formulier

oefeningen

1. Schrijf een functie die in het foutopspringsvenster al de namen van alle eigenschappen van het geopend formulier frmLeerlingen_o afdrukt.
2. Zelfde vraag maar naam en waarde van de eigenschap.
3. Schrijf een functie die in het foutopspringsvenster al de namen van de besturingselementen  van het geopend formulier frmLeerlingen_o afdrukt.
4. Zelfde vraag maar alleen de tekstvakken.
5. De vorige lijst uitbreiden met de inhoud van de tekstvakken.

antwoorden

De volgende tabel toont de structuur.

Enkele bedenkingen

Het DBEngine-object is het object van het hoogste niveau in het DAO-objectmodel .Het bevat en bestuurt alle andere objecten.

Een workspace is een sessie voor een gebruiker. Dit is het werkgebied waar men terecht komt bij het opstarten van access. Workspaces is de collectie van alle workspace-objecten. De default workspace is workspaces(0)

Net zoals bij de Microsoft Access-objecten kunnen de propertiescollectie en de count- en name-eigenschappen gebruikt worden.

Het volgend voorbeeld drukt de namen van de properties van de huidig geopend database.

Function databaseproperties()
Dim db As Database, x As Integer
Set db = CurrentDb
For x = 0 To db.Properties.Count - 1
Debug.Print db.Properties(x).Name
Next x
End Function

Het volgend voorbeeld toont de naam van de huidig geopende database en of hij al of niet updatable is.

Function databaseproperties()
Dim db As Database, x As Integer
Set db = CurrentDb
Debug.Print db.Name
Debug.Print db.Updatable
End Function

8.4 Werken met de hiërarchie van de DAO-objecten

Als voorbeeld nemen met de collectie tabledefs. Dit is de verzameling van de gegevens van alle tabellen.

De volgende functie toont een lijst van alle tabellen uit de actieve database in het foutopsporingsvenster.

Function tabellen()
Dim db As Database, t As TableDef, aantal As Integer, x As Integer
Set db = CurrentDb
aantal = db.TableDefs.Count
For x = 0 To aantal - 1
Debug.Print db.TableDefs(x).Name
Next x
End Function

Elke tabel heeft eigenschappen. Het volgend voorbeeld toont na invoer van de tabelnaam deze eigenschappen. We maken daarbij gebruik van de propertiescollectie.

Function tabeleigenschappen()
Dim db As Database, t As TableDef, tabel As String, x As Integer
Set db = CurrentDb
tabel = InputBox("welke tabel")
Set t = db.TableDefs(tabel)
For x = 0 To t.Properties.Count - 1
Debug.Print t.Properties(x).Name
Next x
End Function

Bemerk de manier waarop de objectvariabele t zijn waarde krijgt. Hier wordt niet het indexnummer gebruikt maar een variabele, namelijk tabel.

De fieldscollectie is dan weer een subcollectie van tabledefs. Het volgend voorbeeld maakt het mogelijk na invoer van een tabel de velden af te drukken.

Function velden_in_tabel()
Dim db As Database, t As TableDef, tabel As String, x As Integer
Set db = CurrentDb
tabel = InputBox("welke tabel")
Set t = db.TableDefs(tabel)
For x = 0 To t.Fields.Count - 1
Debug.Print t.Fields(x).Name
Next x
End Function

of  gebruikmakend van een fieldobject

Function velden_in_tabel()
Dim db As Database, t As TableDef, f As Field, tabel As String, x As Integer
Set db = CurrentDb
tabel = InputBox("welke tabel")
Set t = db.TableDefs(tabel)
For x = 0 To t.Fields.Count - 1
Set f = t.Fields(x)
Debug.Print f.Name
Next x
End Function

oefeningen

1. Maak een lijst in het foutopsporingsscherm met tabelnamen en aantal records voor elke tabel.

2. Zorg dat na invoer van een veldnaam alle tabellen waarin deze veldnaam voorkomt getoond worden.

3. Schrijf een functie die na invoer van een tabelnaam en een veldnaam die in deze tabel voorkomt, de eigenschappen van dat veld afdrukt.

4. Zelfde vraag maar de waarde van het veld moet afgedrukt worden.

antwoorden

8.5 Gevorderde bewerkingen met DAO-objecten

8.5.1 QUERYDEFS

Deze collectie bevat de querydefobjecten. Dit zijn de gegevens i.v.m. query's en de bijhorende sql-commando's. Het sql-commando kan men bekomen met de speciale eigenschap sql.
Het volgende voorbeeld genereert een lijst van bestaande query's uit de actieve database en het bijhorend sql-commando.

Function querylijst()
Dim db As Database, q As QueryDef, x As Integer
Set db = CurrentDb
For x = 0 To db.QueryDefs.Count - 1
Set q = db.QueryDefs(x)
Debug.Print q.Name, q.SQL
Next x
db.close
End Function

Actionquery's kunnen met de execute-methode vanuit een functie uitgevoerd worden. Stel dat de query qryBoeken een bijwerkquery is die de eenheidsprijs van de boeken met 2% verhoogt, dan zal de volgende functie deze query uitvoeren.

Function prijsverhoging()
Dim db As Database, q As QueryDef
Set db = CurrentDb
Set q = db.QueryDefs("qryBoeken")
q.Execute
db.close
End Function

oefeningen

1. Indien een tabelnaam gewijzigd wordt, moeten alle query's gebaseerd op deze tabel, gewijzigd worden. Schrijf een functie die na invoer van een tabelnaam de namen van alle query's waarin deze tabel voorkomt in het foutopsporingsvenster afdrukt. Maak daarbij gebruik van de InStr-instructie.

2. Schrijf een functie die alle query's wist met de deleteobjectmethode..

antwoorden

8.5.2 RECORDSETS

8.5.2.1 Het recordset-object

Het recordsetobject bevat de records van een tabel of het resultaat van een query. De recordsets-collectie bevat alle geopende recordsetobjecten.
Er zijn 4 soorten recordsetobjecten

Een recordset kan men openen met volgende methode

Set recordset = object.OpenRecordset (type, opties, bewerkingenvergrendelen)

waarbij

recordset: de naam van het recordsetobjectvariabel

object: het databaseobject waarin de recordset geopend wordt

type: één van de volgende mogelijkheden dbOpenTable,dbOpenDynaset, dbOpenSnapshot of dbOpenForwardOnly  afhankelijk van wat de bron is van de recordset( tabel of query) of wat je er wil meedoen (dynaset of snapshot)             

opties: afhankelijk van de uit te voeren actie en/of beveiliging kan men kiezen uit één van de volgende mogelijkheden: dbAppendOnly ,dbDenyWrite,dbDenyRead,dbReadOnly         

bewerkingenvergrendelen: kan je gebruiken om te bepalen hoe de recordset moet vergrendeld worden bij gebruik door verschillende users. We onderscheiden o.a.  dbPessimistic en  dbPessimistic. Zoek het verschil via de help.       

Vergeet nooit op het einde van een functie de geopende recordset te sluiten met de close-methode

Het volgend voorbeeld opent en sluit de tabel tblBoeken in een recordset van het type table.

Function open_en_sluiten()
Dim db As Database, r As Recordset
Set db = CurrentDb
Set r = db.OpenRecordset("tblBoeken", dbOpenTable)
r.Close
db.close
End Function

8.5.2.2 Methoden en eigenschappen van het recordsetobject

Een object wordt bestuurd door methoden met als vorm object.methode(argumenten) of object.methode indien geen argumenten.
Bovendien heeft een object ook eigenschappen die een bepaalde waarde bevatten met als schriijfwijze: methode.eigenschap
Wat volgt is een overzicht van de voornaamste eigenschappen en methoden.

de recordcount-eigenschap

Deze eigenschap toont het aantal records van de recordset. Het volgend voorbeeld toont het aantal records van de tabel tblBoeken in het foutopsporingsscherm.

Function aantal_records()
Dim db As Database, r As Recordset
Set db = CurrentDb
Set r = db.OpenRecordset("tblBoeken", dbOpenTable)
debug.print r.Recordcount
r.Close
db.close
End Function

Methoden om een recordset te doorlopen:

De methoden movenext,movefirst,movelast en moveprevious maken het mogelijk de records uit een recordset te doorlopen

De eigenschappen eof (end of file) en bof (begin of file) zijn nodig om te testen op de eerste en laatste record van een recordset.

Wanneer u een Recordset opent, is de eerste record de huidige record en heeft de eigenschap BOF
de instelling False. Als de Recordset geen records bevat, heeft de eigenschap BOF de instelling True en is er geen huidige record.

Het volgend voorbeeld drukt de titels van de tabel tblBoeken in het foutopsporingsvenster

Function doorloop_tabel()
Dim db As Database, r As Recordset
Set db = CurrentDb
Set r = db.OpenRecordset("tblBoeken", dbOpenTable)
Do Until r.EOF
Debug.Print r![titel]
r.MoveNext
Loop
r.close
db.close
End Function

Bemerk de manier waaop een veld uit een recordset wordt aangeduid: object![veldnaam]

Kiezen we voor een dynaset, dan bestaat de mogelijkheid de naam van een bestaande query of zelfs een sqlcommande als recordsetbron te gebruiken. het volgende voorbeeld drukt de gesorteerde titels van de tabel tblBoeken in het foutopsporingsvenster.

Function doorloop_tabel()
Dim db As Database, r As Recordset
Set db = CurrentDb
Set r = db.OpenRecordset("select titel from tblBoeken order by titel", dbOpenDynaset)
Do Until r.EOF
Debug.Print r![titel]
r.MoveNext
Loop
r.close
db.close
End Function

Opgelet: bij het gebruik van de eigenschap recordcount in een dynaset moet men eerst de methode movelast uitvoeren. Het volgende voorbeeld overloopt de tabel boeken met een for-next-instructie van achter naar voor.

Function doorloop_tabel()
Dim db As Database, r As Recordset, x As Integer
Set db = CurrentDb
Set r = db.OpenRecordset("select titel from tblBoeken order by titel", dbOpenDynaset)
r.MoveLast
For x = 1 To r.RecordCount
Debug.Print r![titel]
r.MovePrevious
Next x
r.close
db.close
End Function

Sorteren van een recordset

Er zijn 3 manieren om een recordset gesorteerd te gebuiken.

• Met een bestaande query of sqlcommando en een dynaset (zie vorig voorbeeld).
• Met de index-eigenschap van een tabelrecordset. In de tabel moet dan minstens één index aangemaakt zijn. Een bestaande primary key kan men activeren door in de index-eigenschap de waarde "primarykey" te plaatsen.
  Het volgend voorbeeld drukt het volgnummer en de titel uit de tabel tblBoeken door gebruik te maken van de primary key , gedefinieerd op volgnummer:
  
  Function doorloop_tabel()
  Dim db As Database, r As Recordset, x As Integer
  Set db = CurrentDb
  Set r = db.OpenRecordset("tblBoeken", dbOpenTable)
  r.Index = "primarykey"
  For x = 1 To r.RecordCount
  Debug.Print r![volgnummer], r![titel]
  r.MoveNext
  Next x
  r.close
  db.close
  End Function
• Door een nieuwe recordset aan te maken van het type dynaset of snapshot met de methode sort. Het volgend voorbeeld sorteert de boeken op vakcode en titel
  
  Function doorloop_tabel()
  Dim db As Database, r As Recordset, r1 As Recordset, x As Integer
  Set db = CurrentDb
  Set r = db.OpenRecordset("select * from tblBoeken", dbOpenDynaset)
  r.Sort = "[vakcode],[titel]"
  Set r1 = r.OpenRecordset()
  For x = 1 To r1.RecordCount
  Debug.Print r1![vakcode], r1![titel]
  r1.MoveNext
  Next x
  r.close
  r1.close
  db.close
  End Function
  
  Volgende sorteersleutels zijn ook mogelijk
  r.sort="[vakcode] DESC"
  r.sort="[vakcode] ASC,[titel] DESC"
  

Zoeken in een recordset

De manier van zoeken is afhankelijk van het type recordset, vandaar

• Zoeken in een recordset van het type dynaset of snapshot
  
  Met de methoden FINDFIRST, FINDLAST, FINDNEXT,  FINDPREVIOUS en de NOMATCH-property kan men zoekacties uitvoeren
  
  Het volgend voorbeeld zoekt na invoer van de vakcode de overeenkomstige omschrijving in de tabel tblVakken.
  
  Function zoek_omschrijving()
  Dim db As Database, r As Recordset, code As String, criterium As String
  code = InputBox("Welke code?")
  Set db = CurrentDb
  Set r = db.OpenRecordset("tblVakken", dbOpenDynaset)
  criterium = "[vakcode]='" & code & "'"
  r.FindFirst criterium
  If Not r.NoMatch Then
  MsgBox r![vak_omschrijving]
  Else
  MsgBox "niet gevonden"
  End If
  r.Close
  db.Close
  End Function
  
  Het volgende voorbeeld zoekt na invoer van een vakcode de titels van de boeken in de tabel tblBoeken.
  
  Function zoek_tabel()
  Dim db As Database, r As Recordset, zoekcode As String, criterium As String
  zoekcode = InputBox("welke vakcode")
  criterium = "[vakcode]='" & zoekcode & "'"
  Set db = CurrentDb
  Set r = db.OpenRecordset("select * from tblBoeken", dbOpenDynaset)
  r.FindFirst criterium
  Do Until r.NoMatch
  Debug.Print r![vakcode], r![titel]
  r.FindNext criterium
  Loop
  r.Close
  db.Close
  End Function
  
  
• Zoeken in een recordset van het type table
  
  Met de SEEK-methode en de NOMATCH-property kan men  snel in geïndexeerde tabellen zoeken.
  
  Vak_Kode is de indexnaam van een index op vakcode. De volgende functie geeft hetzelfde resultaat van het vorig voorbeeld, doch sneller.
  
  Function zoek_tabel()
  Dim db As Database, r As Recordset, zoekcode As String
  zoekcode = InputBox("welke vakcode")
  
  Set db = CurrentDb
  Set r = db.OpenRecordset("tblBoeken", dbOpenTable)
  r.Index = "Vak_Kode"
  r.Seek "=", zoekcode
  If Not r.NoMatch Then
      Do Until r![vakcode] <> zoekcode
      Debug.Print r![vakcode], r![titel]
      r.MoveNext
           If r.EOF Then
           Exit Do
           End If
     Loop
  End If
  r.Close
  db.Close
  End Function
  
  opmerking:
  • De extra if die r.eof controleert is nodig indien men als vakcode deze invoert die als laatste voorkomt in de tabel.
  • Indien een index uit verschillende velden bestaat dan kan men met r.seek "=", waarde 1, waarde 2,..., waarde n een zoekactie uitvoeren.
  • Bij het zoeken zijn ook volgende logische operatoren mogelijk: <,>,<=,>=,=, !=
    Wildcards als * en ? zijn niet mogelijk.

Toevoegen in een recordset

De methoden ADDNEW en UPDATE maken het mogelijk records toe te voegen met een functie. Het volgende voorbeeld voegt in de tabel vakken een ingevoerde vakcode en omschrijving toe.

Function toevoegen_in_tabel()
Dim db As Database, r As Recordset, code As String, omschrijving As String
code = InputBox("welke vakcode")
omschrijving = InputBox("welke omschrijving")
Set db = CurrentDb
Set r = db.OpenRecordset("tblVakken", dbOpenTable)
r.AddNew
r![vakcode] = code
r![vak_omschrijving] = omschrijving
r.Update
r.Close
db.Close
End Function

Wat gebeurt er indien één van de invoervelden leeg is? Hoe los je dit op?

Function toevoegen_in_tabel()
Dim db As Database, r As Recordset, code As String, omschrijving As String
code = InputBox("welke vakcode")
omschrijving = InputBox("welke omschrijving")
If code <> Null And omschrijving <> Null Then
     Set db = CurrentDb
     Set r = db.OpenRecordset("tblVakken", dbOpenTable)
     r.AddNew
    r![vakcode] = code
    r![vak_omschrijving] = omschrijving
    r.Update
    r.Close
   db.Close
Else
   Debug.Print "één van de invoervelden was leeg"
End If
End Function

Wijzigen in een recordset

De methoden EDIT en UPDATE maken het mogelijk velden in een record te wijzigen met een functie. Het volgende voorbeeld plaatst alle vak_omschrijvingen in hoofdletters.

Function wijzigen_in_tabel()
Dim db As Database, r As Recordset
Set db = CurrentDb
Set r = db.OpenRecordset("tblVakken", dbOpenTable)
Do Until r.EOF
r.Edit
r![vak_omschrijving] = UCase(r![vak_omschrijving])
r.Update
r.MoveNext
Loop
r.Close
db.Close
End Function

Wissen in een recordset

De methode DELETE volstaat om records in een tabel te wissen. Het volgend voorbeeld wist uit de tabel boeken alle records waar uit_assortiment gelijk is aan ja. Na de delete-actie wordt het aantal gewiste records getoond.

Function wissen_in_tabel()
Dim db As Database, r As Recordset, teller As Integer
Set db = CurrentDb
Set r = db.OpenRecordset("tblBoeken", dbOpenTable)
teller = 0
Do Until r.EOF
If r![uit_assortiment] Then
r.Delete
teller = teller + 1
End If
r.MoveNext
Loop
r.Close
db.Close
MsgBox "er werden " & teller & " records gewist"
End Function

8.5.2.3 Oefeningen met recordsets

1. Voeg in de tabel tblLeerlingen het veld klasnummer (integer ) toe. Schrijf een functie die de leerlingen per klas alfabetisch rangschikt en een klasnummer toekent.
2. Maak een  tabel tblAfwezigheden met als velden naam en datum. Maak een formulier gebaseerd op leerlingen met per formulier de leerlinggegevens en een opdrachtenknop AFWEZIG. Bij het klikken op deze laatste wordt de naam en de systeemdatum in de tabel tblAfwezigheden weggeschreven.
3. In een schoenwinkel moet men een aantal gelijkaardige etiketten kunnen afdrukken. De gegevens op het etiket bestaan maximum uit 3 regels bijvoorbeeld
                        Leder ZWART
                        maat 42
                        type AL56
   Maak een formulier waarin men de gegevens en het aantal exemplaren kan invoeren.
   Daarna worden de etiketten door middel van een rapport in 2 kolommen afgedrukt. Maak daarbij gebruik van een tabel tblEtiket waarin de nodige records worden aangemaakt of gewist.
4. Maak een nieuwe tabel tblRekeningen met als velden naam, kostenomschrijving, bedrag en datum.
   Met een formulier bestaande uit 3 invoervakken: klas, kostenomschrijving en bedrag kan men in groep verrekeningen naar leerlingen aanmaken in de tblRekeningentabel.

Antwoorden

8.5.3 FORMS en ONDERLIGGENDE TABELLEN

Verwijst de recordbroneigenschap van een formulier naar een tabel dan kan deze onderliggende tabel aangesproken worden met de recordsetclone-property. Deze is steeds van het type DYNASET.
De bookmarkproperty maakt synchronisatie tussen formulier en onderliggende dynaset mogelijk.

In formulier frmVakken met vakcode, vak_omschrijving en een opdrachtenknop die verwijst naar de volgende functie toont het probleem van gegevens van het formulier en onderliggende tabel aan.

Function gegevens()
Dim r As Recordset
Set r = Forms![frmVakken].RecordsetClone
MsgBox r![Vakcode]
r.Close
End Function

Als men via de navigatieknoppen een volgende record oproept blijft de functie de eerste record tonen.
Dit kan men oplossen door beiden, formulier en recordsetclone te synchroniseren.

Function gegevens()
Dim r As Recordset
Set r = Forms![frmVakken].RecordsetClone
r.Bookmark = Forms![frmVakken].Bookmark
MsgBox r![Vakcode]
r.Close
End Function

Hierbij fungeert de bookmarkproperty als een recordnummer.

De recordsetcloneproperty bestaat alleen bij formulieren en niet bij rapporten!!!

8.5.4 ERROR TRAPPING ROUTINES

In sommige gevallen is een fout tijdens de uitvoering van een functie (RUNTIME fout) onvermijdelijk. Met de instructie ON ERROR kan men er voor zorgen  dat de functie op een passende  wijze reageert.
We onderscheiden volgende mogelijkheden:

• ON ERROR RESUME NEXT: indien een fout ga naar volgende regel
• ON ERROR GOTO 0 : error trapping wordt uitgeschakeld, fouten worden niet meer opgevangen.
• ON ERROR GOTO label : maak een sprong naar het functiedeel aangeduid met label
  In het functiedeel label kunnen volgende instructies voorkomen:
        RESUME NEXT: keer terug naar de regel die volgt op foutregel
        RESUME: keer terug naar de regel waar de fout voorkwam
        RESUME label1 : ga naar het functiedeel aangeduid met label1

8.5.4.1 Een paar voorbeelden

• Maak een tabel met als naam tblData. Volgende functie maakt het mogelijk de tabel te wissen door oproep vanuit het opsporingsvenster.
  
  Function wis_data()
  DoCmd.DeleteObject A_TABLE, "tblData"
  End Function
  
  Indien de tabel niet bestaat krijgt men een foutmelding tenzij
  
  Function wis_data()
  On Error Resume Next
  DoCmd.DeleteObject A_TABLE, "tblData"
  End Function
• Met het commando DIR(bestandsspecificatie) kan men een bestandenlijst opvragen van bijvoorbeeld c:\access\*.*
  
  Function bestandenlijst()
  Dim lijst As String, bestandsnaam As String
  lijst = InputBox("welke bestanden")
  bestandsnaam = Dir(lijst)
  If Len(bestandsnaam) <> 0 Then
  Do
  Debug.Print bestandsnaam
  bestandsnaam = Dir
  Loop Until Len(bestandsnaam) = 0
  End If
  End Function
  
  Er onstaat echter een foutmelding indien a:\*.* wordt ingevoerd en er geen floppy in drive A aanwezig is. Dit probleem kunnen we oplossen door een MSGBOX te voorzien met de keuzes OK (indien floppy ondertussen aanwezig) en ANNULEREN (indien geen floppy aanwezig).
  
  Function bestandenlijst()
  On Error GoTo fout
  Dim lijst As String, bestandsnaam As String, keuze As Integer
  lijst = InputBox("welke bestanden")
  bestandsnaam = Dir(lijst)
  If Len(bestandsnaam) <> 0 Then
  Do
  Debug.Print bestandsnaam
  bestandsnaam = Dir
  Loop Until Len(bestandsnaam) = 0
  End If
  einde:
  Exit Function
  
  fout:
  keuze = MsgBox("geen floppy in drive A", 49)
  If keuze = 1 Then
  Resume
  Else
  Resume einde
  End If

8.5.4.2 Oefeningen

1. Maak een formulier gebaseerd op de tabel tblKlassen. Voorzie 2 toetsen voor vorige en volgende record, gebruik hierbij de macroactie GOTORECORD. Zorg dat er geen foutmeldingen verschijnen bij  de laatste en eerste record.
   Als uitbreiding zorg je dat volgende record op de laatste, resulteert in de eerste record en vorige record op de eerste de laatste record toont.
2. Schrijf een functie dat na invoer van maand en jaar het aantal dagen van deze maand toont.

Antwoorden